Hi guys,
Still not working, this is how it looks now, I tried adding the """" straight after the %gametitle% and then again with a space to see if that would work and it didnt.
The : I was talking about isnt in the script, its in the title of the games name so for some reason this script wont recognise the puncuation and wont change the game folder name because it doesnt understand what the character is.
The error message I get is ERROR (line 1):(callfile)"ActionScript file failed execution" if that helps. All the other game folders renamed ok and this is the only thing the ones that didnt have in common.
Has anyone else had this problem with NFS Underground, Dues Ex Invisible Wars and Spawn Armageddon?
Anyway guys see what you think and let me know if its fixable.
Thanks for your time and help and Ben shouldnt you be working on the new mxm dash
<Action>
;PxHDDLoader Renamer MXM Action Script
;Written by DBZRacer
;Purpose: This MXM action script searches for folders created by PxHDDLoader in your E and F drive and
;prompts you if you want to rename the undescriptive PXGame0000 folder name to the more descriptive XBE Title.
:Start
BeginDraw UseCurrent
MessageBox " - PxHDDLoader Folder Renamer - $eol$Press X to Rename folders in Drive E$eol$Press Y to Rename folders in Drive F$eol$Press B to Cancel"
EndDraw
Input
If %_GP_Y% == "1" GOTO FDriveSelected
If %_GP_X% == "1" GOTO EDriveSelected
If %_GP_B% == "1" GOTO Cancel
Quit
:FDriveSelected
SETFUNC FolderEmpty PATHEMPTY F:\hddloader
IF %FolderEmpty% == "1" GOTO FolderNotFound
SET HDDLoaderPath "F:\\hddloader"
GOTO DefineSearch
:EDriveSelected
SETFUNC FolderEmpty PATHEMPTY E:\hddloader
IF %FolderEmpty% == "1" GOTO FolderNotFound
SET HDDLoaderPath "E:\\hddloader"
GOTO DefineSearch
:FolderNotFound
BeginDraw UseCurrent
MessageBox "PxHDDLoader Root Folder Not Found on Drive"
EndDraw
Delay 2
QUIT
:DefineSearch
BEGINSEARCH %HDDLoaderPath%\pxgame*
GOTO SearchTop
:SearchTop
IF %search_type% == "dir" GOTO DIRFound
IF %search_type% == "file" GOTO NextSearch
GOTO DoneSearch
:DIRFound
SETFUNC GameTitle XBETITLE %HDDLoaderPath%\%search_name%\default.xbe
SETFUNC Temp FatXify %GameTitle% ""
Set GoodTitle %Temp%
BeginDraw UseCurrent
MessageBox "%GameTitle% found in %search_name% folder$eol$Press Y to RENAME %search_name% to %GameTitle%$eol$Press A to Skip to next folder$eol$Press B to Cancel Script"
EndDraw
Input
If %_GP_Y% == "1" GOTO RenameFolder
If %_GP_A% == "1" GOTO NextSearch
If %_GP_B% == "1" GOTO Cancel
Quit
:RenameFolder
RENAME %HDDLoaderPath%\%search_name% %HDDLoaderPath%\%GoodTitle%
BeginDraw UseCurrent
MessageBox "%search_name% has been renamed to %GameTitle%$eol$Press A to find next match$eol$Press B to Cancel Script"
EndDraw
Input
If %_GP_A% == "1" GOTO NextSearch
If %_GP_B% == "1" GOTO Cancel
Quit
:NextSearch
SearchNext
GOTO SearchTop
:Cancel
BeginDraw UseCurrent
MessageBox "PHDDLoader Folder Renamer Action Script Cancelled"
EndDraw
DELAY 5
QUIT
:DoneSearch
EndSearch
BeginDraw UseCurrent
MessageBox "PxHDDLoader Folder Renamer$eol$ Completed $eol$ Please REBOOT XBOX NOW $eol$ for changes to take effect"
EndDraw
DELAY 10
ResetMenuCache
QUIT
</Action>